rofi-extras/app/rofi-autorandr.hs

--------------------------------------------------------------------------------
-- rofi-autorandr - a rofi prompt to select autorandr profiles
--
-- Simple wrapper to select an autorandr profile.

module Main (main) where

import Control.Monad
import Data.Maybe
import qualified Data.Text.IO as TI
import RIO
import qualified RIO.Text as T
import Rofi.Command
import System.Directory
import System.Environment
import System.FilePath.Posix
import System.Process

main :: IO ()
main = runChecks >> getArgs >>= runPrompt

-- TOOD not DRY
runChecks :: IO ()
runChecks = checkExe "autorandr" >> checkExe "rofi"

checkExe :: String -> IO ()
checkExe cmd = do
  res <- findExecutable cmd
  unless (isJust res) $ do
    TI.putStrLn $ T.append "Could not find executable: " $ T.pack cmd
    exitWith $ ExitFailure 1

newtype ARClientConf = ARClientConf [T.Text]

instance HasRofiConf ARClientConf where
  defArgs (ARClientConf a) = a

runPrompt :: [String] -> IO ()
runPrompt a = do
  let c = ARClientConf $ fmap T.pack a
  staticProfs <- getAutoRandrProfiles
  runRofi c $
    emptyMenu
      { groups = [mkGroup "Static" staticProfs, mkGroup "Virtual" virtProfs]
      , prompt = Just "Select Profile"
      }
  where
    mkGroup header =
      titledGroup header
        . toRofiActions
        . fmap (\s -> (T.append "  " s, selectProfile s))

virtProfs :: [T.Text]
virtProfs = ["off", "common", "clone-largest", "horizontal", "vertical"]

-- TODO filter profiles based on which xrandr outputs are actually connected
getAutoRandrProfiles :: IO [T.Text]
getAutoRandrProfiles = do
  dir <- getAutoRandrDir
  contents <- listDirectory dir
  (fmap T.pack) <$> filterM (doesDirectoryExist . (dir </>)) contents

getAutoRandrDir :: IO FilePath
getAutoRandrDir = do
  c <- getXdgDirectory XdgConfig "autorandr"
  e <- doesDirectoryExist c
  if e then return c else appendToHome ".autorandr"
  where
    appendToHome p = (</> p) <$> getHomeDirectory

selectProfile :: T.Text -> RIO ARClientConf ()
selectProfile name = liftIO $ do
  TI.putStrLn name
  void $ spawnProcess "autorandr" ["--change", T.unpack name]