xmonad-config/lib/Xmobar/Plugins/Common.hs

{-# LANGUAGE OverloadedStrings #-}

module Xmobar.Plugins.Common
  ( colorText
  , startListener
  , procSignalMatch
  , na
  , fromSingletonVariant
  , withDBusClientConnection
  , Callback
  , Colors(..)
  , displayMaybe
  , displayMaybe'
  , xmobarFGColor
  )
  where

import           Control.Monad

import           Data.Internal.DBus

import           DBus
import           DBus.Client

import qualified RIO.Text                as T

import           XMonad.Hooks.DynamicLog (xmobarColor)

-- use string here since all the callbacks in xmobar use strings :(
type Callback = String -> IO ()

data Colors = Colors
  { colorsOn  :: T.Text
  , colorsOff :: T.Text
  }
  deriving (Eq, Show, Read)

startListener :: (SafeClient c, IsVariant a) => MatchRule -> (c -> IO [Variant])
  -> ([Variant] -> SignalMatch a) -> (a -> IO T.Text) -> Callback
  -> c -> IO ()
startListener rule getProp fromSignal toColor cb client = do
  reply <- getProp client
  displayMaybe cb toColor $ fromSingletonVariant reply
  void $ addMatchCallback rule (procMatch . fromSignal) client
  where
    procMatch = procSignalMatch cb toColor

procSignalMatch :: Callback -> (a -> IO T.Text) -> SignalMatch a -> IO ()
procSignalMatch cb f = withSignalMatch (displayMaybe cb f)

colorText :: Colors -> Bool -> T.Text -> T.Text
colorText Colors { colorsOn = c } True   = xmobarFGColor c
colorText Colors { colorsOff = c } False = xmobarFGColor c

xmobarFGColor :: T.Text -> T.Text -> T.Text
xmobarFGColor c = T.pack . xmobarColor (T.unpack c) "" . T.unpack

na :: T.Text
na = "N/A"

displayMaybe :: Callback -> (a -> IO T.Text) -> Maybe a -> IO ()
displayMaybe cb f = (cb . T.unpack) <=< maybe (return na) f

displayMaybe' :: Callback -> (a -> IO ()) -> Maybe a -> IO ()
displayMaybe' cb = maybe (cb $ T.unpack na)

withDBusClientConnection :: SafeClient c => Callback -> (c -> IO ()) -> IO ()
withDBusClientConnection cb f = displayMaybe' cb f =<< getDBusClient