{-# LANGUAGE OverloadedStrings #-}

--------------------------------------------------------------------------------
-- Bluetooth plugin
--
-- Use the bluez interface on DBus to check status
--
-- org.bluez dynamically updates its DBus interfaces using the standard Object
-- Manager. The adapter is located at path "/org/bluez/hci<X>" where X is
-- usually 0, and each device is "/org/bluez/hci<X>/<MAC_ADDRESS>".
--
-- This plugin will reflect if the adapter is powered and if any device is
-- connected to it. The rough outline for this procedure:
-- 1) get the adapter from the object manager
-- 2) get all devices associated with the adapter using the object interface
-- 3) determine if the adapter is powered
-- 4) determine if any devices are connected
-- 5) format the icon; powered vs not powered controls the color and connected
--    vs not connected controls the icon (connected bluetooth symbol has two
--    dots flanking it)
--
-- Step 3 can be accomplished using the "org.bluez.Adapter1" interface and
-- querying the "Powered" property. Step 4 can be done using the
-- "org.bluez.Device1" interface and the "Connected" property for each device
-- path. Since these are properties, we can asynchronously read changes to them
-- via the "PropertiesChanged" signal.
--
-- If any devices are added/removed, steps 2-4 will need to be redone and any
-- listeners will need to be updated. (TODO not sure which signals to use in
-- determining if a device is added)
--
-- TODO also not sure if I need to care about multiple adapters and/or the
-- adapter changing.

module Xmobar.Plugins.Bluetooth
  ( Bluetooth (..)
  , btAlias
  , btDep
  )
where

import Control.Monad
import DBus
import DBus.Client
import Data.Internal.DBus
import Data.Internal.Dependency
import Data.List
import Data.List.Split
import qualified Data.Map as M
import Data.Maybe
import RIO
import qualified RIO.Text as T
import XMonad.Internal.DBus.Common
import Xmobar
import Xmobar.Plugins.Common

btAlias :: T.Text
btAlias = "bluetooth"

btDep :: DBusDependency_ SysClient
btDep =
  Endpoint [Package Official "bluez"] btBus btOMPath omInterface $
    Method_ getManagedObjects

data Bluetooth = Bluetooth Icons Colors deriving (Read, Show)

instance Exec Bluetooth where
  alias (Bluetooth _ _) = T.unpack btAlias
  start (Bluetooth icons colors) cb =
    withDBusClientConnection cb $ startAdapter icons colors cb

startAdapter
  :: MonadUnliftIO m
  => Icons
  -> Colors
  -> Callback
  -> SysClient
  -> m ()
startAdapter is cs cb cl = do
  ot <- getBtObjectTree cl
  state <- newMVar emptyState
  let dpy = displayIcon cb (iconFormatter is cs) state
  forM_ (findAdapter ot) $ \adapter -> do
    -- set up adapter
    initAdapter state adapter cl
    -- TODO this step could fail; at least warn the user...
    void $ addAdaptorListener state dpy adapter cl
    -- set up devices on the adapter (and listeners for adding/removing devices)
    let devices = findDevices adapter ot
    addDeviceAddedListener state dpy adapter cl
    addDeviceRemovedListener state dpy adapter cl
    forM_ devices $ \d -> addAndInitDevice state dpy d cl
    -- after setting things up, show the icon based on the initialized state
    dpy

--------------------------------------------------------------------------------
-- Icon Display
--
-- Color corresponds to the adaptor powered state, and the icon corresponds to
-- if it is paired or not. If the adaptor state is undefined, display "N/A"

type IconFormatter = (Maybe Bool -> Bool -> T.Text)

type Icons = (T.Text, T.Text)

displayIcon :: MonadUnliftIO m => Callback -> IconFormatter -> MutableBtState -> m ()
displayIcon callback formatter =
  liftIO . callback . T.unpack . uncurry formatter <=< readState

-- TODO maybe I want this to fail when any of the device statuses are Nothing
iconFormatter :: Icons -> Colors -> IconFormatter
iconFormatter (iconConn, iconDisc) cs powered connected =
  maybe na (\p -> colorText cs p icon) powered
  where
    icon = if connected then iconConn else iconDisc

--------------------------------------------------------------------------------
-- Connection State
--
-- The signal handlers all run on separate threads, yet the icon depends on
-- the state reflected by all these signals. The best (only?) way to do this is
-- is to track the shared state of the bluetooth adaptor and its devices using
-- an MVar.

data BTDevice = BTDevice
  { btDevConnected :: Maybe Bool
  , btDevSigHandler :: SignalHandler
  }

type ConnectedDevices = M.Map ObjectPath BTDevice

data BtState = BtState
  { btDevices :: ConnectedDevices
  , btPowered :: Maybe Bool
  }

type MutableBtState = MVar BtState

emptyState :: BtState
emptyState =
  BtState
    { btDevices = M.empty
    , btPowered = Nothing
    }

readState :: MonadUnliftIO m => MutableBtState -> m (Maybe Bool, Bool)
readState state = do
  p <- readPowered state
  c <- readDevices state
  return (p, anyDevicesConnected c)

--------------------------------------------------------------------------------
-- Object manager

findAdapter :: ObjectTree -> Maybe ObjectPath
findAdapter = find (("/org/bluez/hci" `isPrefixOf`) . formatObjectPath) . M.keys

findDevices :: ObjectPath -> ObjectTree -> [ObjectPath]
findDevices adapter = filter (adaptorHasDevice adapter) . M.keys

adaptorHasDevice :: ObjectPath -> ObjectPath -> Bool
adaptorHasDevice adaptor device = case splitPath device of
  [org, bluez, hciX, _] -> splitPath adaptor == [org, bluez, hciX]
  _ -> False

splitPath :: ObjectPath -> [T.Text]
splitPath = fmap T.pack . splitOn "/" . dropWhile (== '/') . formatObjectPath

getBtObjectTree :: MonadUnliftIO m => SysClient -> m ObjectTree
getBtObjectTree sys = callGetManagedObjects sys btBus btOMPath

btOMPath :: ObjectPath
btOMPath = objectPath_ "/"

addBtOMListener :: MonadUnliftIO m => SignalCallback m -> SysClient -> m ()
addBtOMListener sc = void . addInterfaceAddedListener btBus btOMPath sc

addDeviceAddedListener
  :: MonadUnliftIO m
  => MutableBtState
  -> m ()
  -> ObjectPath
  -> SysClient
  -> m ()
addDeviceAddedListener state dpy adapter client =
  addBtOMListener addDevice client
  where
    addDevice = pathCallback adapter dpy $ \d ->
      addAndInitDevice state dpy d client

addDeviceRemovedListener
  :: (MonadUnliftIO m)
  => MutableBtState
  -> m ()
  -> ObjectPath
  -> SysClient
  -> m ()
addDeviceRemovedListener state dpy adapter sys =
  addBtOMListener remDevice sys
  where
    remDevice = pathCallback adapter dpy $ \d -> do
      old <- removeDevice state d
      forM_ old $ liftIO . removeMatch (toClient sys) . btDevSigHandler

pathCallback :: MonadUnliftIO m => ObjectPath -> m () -> (ObjectPath -> m ()) -> SignalCallback m
pathCallback adapter dpy f [device, _] = forM_ (fromVariant device) $ \d ->
  when (adaptorHasDevice adapter d) $ f d >> dpy
pathCallback _ _ _ _ = return ()

--------------------------------------------------------------------------------
-- Adapter

initAdapter
  :: (MonadUnliftIO m)
  => MutableBtState
  -> ObjectPath
  -> SysClient
  -> m ()
initAdapter state adapter client = do
  reply <- callGetPowered adapter client
  putPowered state $ fromSingletonVariant reply

matchBTProperty
  :: (MonadUnliftIO m)
  => SysClient
  -> ObjectPath
  -> m (Maybe MatchRule)
matchBTProperty sys p = matchPropertyFull sys btBus (Just p)

addAdaptorListener
  :: MonadUnliftIO m
  => MutableBtState
  -> m ()
  -> ObjectPath
  -> SysClient
  -> m (Maybe SignalHandler)
addAdaptorListener state dpy adaptor sys = do
  rule <- matchBTProperty sys adaptor
  forM rule $ \r -> addMatchCallback r (procMatch . matchPowered) sys
  where
    procMatch = withSignalMatch $ \b -> putPowered state b >> dpy

callGetPowered :: MonadUnliftIO m => ObjectPath -> SysClient -> m [Variant]
callGetPowered adapter =
  callPropertyGet btBus adapter adapterInterface $
    memberName_ $
      T.unpack adaptorPowered

matchPowered :: [Variant] -> SignalMatch Bool
matchPowered = matchPropertyChanged adapterInterface adaptorPowered

putPowered :: MonadUnliftIO m => MutableBtState -> Maybe Bool -> m ()
putPowered m ds = modifyMVar_ m (\s -> return s {btPowered = ds})

readPowered :: MonadUnliftIO m => MutableBtState -> m (Maybe Bool)
readPowered = fmap btPowered . readMVar

adapterInterface :: InterfaceName
adapterInterface = interfaceName_ "org.bluez.Adapter1"

adaptorPowered :: T.Text
adaptorPowered = "Powered"

--------------------------------------------------------------------------------
-- Devices

addAndInitDevice
  :: MonadUnliftIO m
  => MutableBtState
  -> m ()
  -> ObjectPath
  -> SysClient
  -> m ()
addAndInitDevice state dpy device client = do
  sh <- addDeviceListener state dpy device client
  -- TODO add some intelligent error messages here
  forM_ sh $ \s -> initDevice state s device client

initDevice
  :: MonadUnliftIO m
  => MutableBtState
  -> SignalHandler
  -> ObjectPath
  -> SysClient
  -> m ()
initDevice state sh device sys = do
  reply <- callGetConnected device sys
  void $
    insertDevice state device $
      BTDevice
        { btDevConnected = fromVariant =<< listToMaybe reply
        , btDevSigHandler = sh
        }

addDeviceListener
  :: MonadUnliftIO m
  => MutableBtState
  -> m ()
  -> ObjectPath
  -> SysClient
  -> m (Maybe SignalHandler)
addDeviceListener state dpy device sys = do
  rule <- matchBTProperty sys device
  forM rule $ \r -> addMatchCallback r (procMatch . matchConnected) sys
  where
    procMatch = withSignalMatch $ \c -> updateDevice state device c >> dpy

matchConnected :: [Variant] -> SignalMatch Bool
matchConnected = matchPropertyChanged devInterface devConnected

callGetConnected :: MonadUnliftIO m => ObjectPath -> SysClient -> m [Variant]
callGetConnected p =
  callPropertyGet btBus p devInterface $
    memberName_ (T.unpack devConnected)

insertDevice
  :: MonadUnliftIO m
  => MutableBtState
  -> ObjectPath
  -> BTDevice
  -> m Bool
insertDevice m device dev = modifyMVar m $ \s -> do
  let new = M.insert device dev $ btDevices s
  return (s {btDevices = new}, anyDevicesConnected new)

updateDevice
  :: MonadUnliftIO m
  => MutableBtState
  -> ObjectPath
  -> Maybe Bool
  -> m Bool
updateDevice m device status = modifyMVar m $ \s -> do
  let new = M.update (\d -> Just d {btDevConnected = status}) device $ btDevices s
  return (s {btDevices = new}, anyDevicesConnected new)

anyDevicesConnected :: ConnectedDevices -> Bool
anyDevicesConnected = or . mapMaybe btDevConnected . M.elems

removeDevice
  :: MonadUnliftIO m
  => MutableBtState
  -> ObjectPath
  -> m (Maybe BTDevice)
removeDevice m device = modifyMVar m $ \s -> do
  let devs = btDevices s
  return (s {btDevices = M.delete device devs}, M.lookup device devs)

readDevices :: MonadUnliftIO m => MutableBtState -> m ConnectedDevices
readDevices = fmap btDevices . readMVar

devInterface :: InterfaceName
devInterface = interfaceName_ "org.bluez.Device1"

devConnected :: T.Text
devConnected = "Connected"